<Exemplo de como carregar um ficheiro XML no Flash ⁄ >

12760

2006-10-07

mySnippets actionscript

Download

Bookmark This

O objectivo deste snippet é tentar dar um exemplo simples de como carregar informação de um ficheiro XML. Existe cada vez uma maior necessidade de tornar o Flash "dinâmico", ou seja, ler certos conteúdos dinâmicamente. Como por exemplo temos as imagens, se tivermos um swf com 20 imagens torna-se um pouco pesado (mesmo nos dias que correm que a banda larga está cada vez mais implantada) e existe mesmo a forte probabilidade de dessas X imagens, poucas ou até mesmo nenhuma ser vista, é aí que poderão entrar os conteúdos dinâmicos (neste meu exemplo o xml, mas também poderão ser usados txt, php, asp, etc, etc). Os conteúdos são carregados consoante se verifique a sua necessidade.

nota: sugiro que consultem o meu snippet de como gerar xml dinâmicamente, esse exemplo poderá ser adaptado a este caso.

Ficheiro XML que o flash irá ler e a partir do qual irá construir toda a informação. Claro que a estrutura não terá de ser necessariamente esta, porém o restante código é baseado nesta mesma. O encoding é o UTF-8, penso que o Actionscript têm alguns problemas com outros encodings e como tal recomendo que usem sempre este.

<?xml version="1.0" encoding="utf-8"?>
<xml>
  <pedrocorreia.net>
    <work titulo="Primeiro Trabalho" data="2006">
      <imagem url="imagem1.jpg" />
      <imagem url="imagem2.jpg" />
    </work>
 
    <work titulo="Segundo Trabalho" data="2004">
      <imagem url="imagem3.jpg" />
      <imagem url="imagem4.jpg" />
    </work>
 
  </pedrocorreia.net>
</xml>

Class Portfolio que irá armazenar todas as informações necessárias que são provenientes do XML, deverá estar num ficheiro chamado Portfolio.as.
nota: recomendo vivamente consultem informação respectiva as classes do Actionscript, mas para este exemplo esta class é bastante simples e de fácil compreensão.

class Portfolio {
	private var titulo:String;
	private var data:String;
	private var imagens:Array;
 
	/**
	 * Método constuctor da class Portfolio
	 *
	 * @param String  titulo - titulo do work
	 * @param String data - data do work
	 * @param Array imagens - array de imagens
	 */
	function Portfolio (titulo:String, data:String, imagens:Array) {
		this.titulo = titulo;
		this.data = data;
		this.imagens = imagens;
	}
 
	/**
	 * Obter titulo do work
	 *
	 * @return String
	 */
	function getTitulo ():String {return this.titulo;}
 
	/**
	 * Obter data do work
	 *
	 * @return  String
	 */
	function getData ():String {return this.data;}
 
	/**
	 * Obter imagem
	 *
	 * @param int posição do array
	 * @return  Array
	 */
	function getImagem (pos:Number):Array {return this.imagens[pos];}
 
	/**
	 * Obter número de imagens
	 *
	 * @return int
	 */
	function getNumImagens ():Number {return this.imagens.length;}
}

Este código deverá estar "dentro" do Flash; ou então poderão criar um ficheiro à parte e depois no Flash fazendo então o #include "nome_do_ficheiro_a_parte.as".
Neste exemplo existem duas funções, o loadInformacoes e o showImagem.

O loadInformacoes consiste em ler o ficheiro xml e armazená-lo para memória para ser usado posteriormente, tomem em atenção as variaveis "no" e "work", a variável "no" vai andar no ficheiro até se posicionar no 1º trabalho (se optarem por uma estrutura diferente da que eu utilizo, terão de modificar esta variável, pois esta mesma vai ser usada por outras variáveis), a variável "no" pode ser vista como um atalho, se por exemplo esta não existisse para obtermos o work teriamos de fazer x.firstChild.firstChild.childNodes (grande combóio de código já devem estar a pensar), colocando o "apontador" do no directamente no x.firstChild.firstChild, irá facilitar muito o código, tanto na compreensão como na leitura

O loadImagem, como o próprio nome indica irá carregar uma imagem pretendida para um determinado movieclip. É tão somente um exemplo do que poderá ser feito com a informação do xml, poderiamos também ter funções para mostrar outras quaisquer informações.

/**
* Carregar informações
*
* @param String xml_file - nome do ficheiro
*/
_global.loadInformacoes = function (xml_file:String) {
 
	var x = new XML (); //criar o objecto
	x.ignoreWhite = true; //necessário para que o ficheiro xml possa ser lido correctamente
	x.load (xml_file); //carregar ficheiro
	x.onLoad = function (success) { //o ficheiro foi carregado com sucesso
		var no = x.firstChild.firstChild; //vamos posicionar o "cursor" no <xml><pedrocorreia.net>
		var work = no.childNodes; //vamos ler todos os nós desse work
		arrInformacoes = new Array (); //criação do array onde vão ser armazenados os objectos
		for (var i:Number = 0; i<work.length; i++) {
			var imagens = work[i].childNodes; //visto que um work pode ter várias imagens, vamos querer percorrer essas imagens todas
			var portfolio = new Portfolio (work[i].attributes.titulo, work[i].attributes.data, imagens); //criação do objecto portfolio
			arrInformacoes.push (portfolio); //adicionar ao array o objecto
		}
	};
};
 
/**
* Mostrar imagem de um trabalho especifico
*
* @param int - indice da imagem
* @param int - indice da imagem
* @param MovieClip - movieclip onde será¡ visualizada a imagem
*/
_global.showImagem = function (idxWork:Number, idxImagem:Number, mc:MovieClip) {
	var img:String = arrInformacoes[idxWork].getImagem (idxImagem).attributes.url; //obter o url da imagem
	mc.loadMovie (img); //efectuar o load da imagem
};

Qualquer dúvida/ erro no código estejam à vontade para entrar em contacto comigo.

12760

2006-10-07

mySnippets actionscript

Download

Bookmark This